SuperCollider: La source

(
{
d = Mix.ar(Array.fill(10, { Resonz.ar(Dust.ar(0.2, 50), rrand(200, 3200.0), 0.003)}) );
z = DelayN.ar(d, 0.048);
y = Mix.ar(Array.fill(7,{ CombL.ar(z, 0.1, LFNoise1.kr(0.1.rand, 0.04, 0.05), 15) })); 
4.do({ y = AllpassN.ar(y, 0.050, [0.050.rand, 0.050.rand], 1) });
d+(0.2*y)
}.play 
)

La source

//impulsion avec placement temporel aléatoire, densité reglable

{ Dust.ar(density: 0.2, mul: 50) }.play;

//l`impulsion "nourrit" un résonateur avec fréquence centrale aléatoire

{ Resonz.ar( Dust.ar(0.2, 50), freq: rrand(200, 3200.0), bwr: 0.003) }.play //frequence aléatoire entre 200 et 3200, largeur de bande fine

// dix source similaires sont mixées ensembles

{ Mix.ar(Array.fill(10, { Resonz.ar(Dust.ar(0.2, 50), rrand(200, 3200.0), 0.003) } ) ) }.play;

//shortcut:

{ Mix.ar( { Resonz.ar(Dust.ar(0.2, 50), rrand(200, 3200.0), 0.003) }!10 ) }.play;

Réverbération (pas chère)

// prédelai  :
(
{ 
d = Mix.ar(Array.fill(10, { Resonz.ar(Dust.ar(0.2, 50), rrand(200, 3200.0), 0.003)}) );
z = DelayN.ar(in: d, maxdelaytime: 0.048); //source, temps de retard
}.play
)
 
// premières reflections  :
(
{ 
d = Mix.ar(Array.fill(10, { Resonz.ar(Dust.ar(0.2, 50), rrand(200, 3200.0), 0.003)}) );
z = DelayN.ar(d, 0.048); //predélai
        
 // 7 comb delays  de longeur modulée, en parallèle : 
y = Mix.ar(Array.fill(7,{ CombL.ar(z, 0.1, LFNoise1.kr(0.1.rand, 0.04, 0.05), 15) })); 
 
}.play
)

Spatialisation

(

{

d = Mix.ar(Array.fill(10, { Resonz.ar(Dust.ar(0.2, 50), rrand(200, 3200.0), 0.003)}) );

z = DelayN.ar(d, 0.048);

y = Mix.ar(Array.fill(7,{ CombL.ar(z, 0.1, LFNoise1.kr(0.1.rand, 0.04, 0.05), 15) }));

// deux chaînes parallèles de 4 delays allpass (8 au total) :

4.do({ y = AllpassN.ar(y, 0.050, [0.050.rand, 0.050.rand], 1) }); // lArray [0.050.rand, 0.050.rand] crée une expansion stétéo

//noter que la variable y est redéfinie à chaque passage dans l`itération 4.do

//mixage du son original et de la réverbération :

d + (0.2 * y)

}.play

)

SuperCollider : JmcExemple2

La source

Réverbération (pas chère)

Spatialisation